From 6a5c473653f03aee818d835b53ca30b62a3be6c7 Mon Sep 17 00:00:00 2001
From: Ralph Amissah <ralph.amissah@gmail.com>
Date: Tue, 12 May 2020 17:11:53 -0400
Subject: meson using subproject directory, not dub directly

- will not work until meson.build files in
  - d2sqlite3
  - imageformats
  (request adding upstream)
  - dyaml and its dependency tinyendian already
    provide their meson.build
  (should probably revert to meson dub until
  resolved)
- based on 1468425 meson build (no issue now with
  imagefomats using 7.0.2)
---
 subprojects/d2sqlite3.meson.build | 48 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 subprojects/d2sqlite3.meson.build

(limited to 'subprojects/d2sqlite3.meson.build')

diff --git a/subprojects/d2sqlite3.meson.build b/subprojects/d2sqlite3.meson.build
new file mode 100644
index 0000000..1685738
--- /dev/null
+++ b/subprojects/d2sqlite3.meson.build
@@ -0,0 +1,48 @@
+project('d2sqlite3', 'd',
+  meson_version: '>=0.46',
+  license: 'BSL-1.0',
+  version: '0.18.3'
+)
+
+project_soversion = '0'
+
+src_dir = include_directories('source/')
+pkgc = import('pkgconfig')
+
+sqlite_dep = dependency('sqlite3')
+
+d2sqlite3_src = [
+  'source/d2sqlite3/database.d',
+  'source/d2sqlite3/internal/memory.d',
+  'source/d2sqlite3/internal/util.d',
+  'source/d2sqlite3/library.d',
+  'source/d2sqlite3/package.d',
+  'source/d2sqlite3/results.d',
+  'source/d2sqlite3/sqlite3.d',
+  'source/d2sqlite3/statement.d',
+]
+install_subdir('source/d2sqlite3/', install_dir: 'include/d/d2sqlite3/')
+
+d2sqlite3_lib = library('d2sqlite3',
+  [d2sqlite3_src],
+  include_directories: [src_dir],
+  dependencies: [sqlite_dep],
+  install: true,
+  version: meson.project_version(),
+  soversion: project_soversion
+)
+
+pkgc.generate(name: 'd2sqlite3',
+  libraries: d2sqlite3_lib,
+  subdirs: 'd/d2sqlite3/',
+  version: meson.project_version(),
+  requires: ['sqlite3'],
+  description: 'A small wrapper around SQLite for the D programming language.'
+)
+
+# for use by others which embed this as subproject
+d2sqlite3_dep = declare_dependency(
+  link_with: [d2sqlite3_lib],
+  dependencies: [sqlite_dep],
+  include_directories: [src_dir]
+)
-- 
cgit v1.2.3