/+
- Name: SisuDoc Spine
- Description: part of SiSU spine (Doc Reform):
for document structuring, processing, publishing and search
- Author: Ralph Amissah
[ralph.amissah@gmail.com]
- Copyright: (C) 2015 (continuously updated, current 2026) Ralph Amissah,
All Rights Reserved.
- License: AGPL 3 or later, for everything in this repository unless a file or
a directory specifies otherwise.
This program is free software: you can redistribute it and/or modify it
under the terms of the GNU Affero General Public License (AGPLv3) as
published by the Free Software Foundation (FSF), either version 3 of the
License, or (at your option) any later version.
This program is distributed in the hope that it will be useful, but WITHOUT
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
FITNESS FOR A PARTICULAR PURPOSE. See the GNU Affero General Public License
for more details.
You should have received a copy of the GNU Affero General Public License
along with this program. If not, see [https://www.gnu.org/licenses/].
If you have Internet connection, the latest version of the AGPL should be
available at: [https://www.gnu.org/licenses/agpl-3.0.html]
- Spine (by Doc Reform, related to SiSU) uses standard:
- docReform markup syntax
- standard SiSU markup syntax with modified headers and minor modifications
- docReform object numbering
- standard SiSU object citation numbering & system
- Homepages:
[https://www.sisudoc.org]
[https://www.doc-reform.org]
- Git
[https://git.sisudoc.org/]
+/
/++
output hub
check & generate output types requested
+/
module sisudoc.outputs.io_out.hub;
@safe:
template outputHub() {
import sisudoc.outputs.io_out;
import sisudoc.outputs.io_out.metadata;
import sisudoc.outputs.io_out.xmls;
import sisudoc.outputs.io_out.zip_pod;
import sisudoc.outputs.io_out.paths_output;
@system void outputHub(D)(D doc) {
mixin Msg;
auto msg = Msg!()(doc.matters);
/+ ↓ the po4a configuration, printed rather than written.
Spine does not write into a source tree, and this belongs beside the
catalogues in the pod it describes, so it goes to stdout for the
caller to put where they want it:
spine --po4a-cfg > /tools/po4a/po4a.cfg
Once per document, not once per language: it is generated from the
source language's files and names every other language itself.
+/
if (doc.matters.opt.action.po4a_cfg
&& doc.matters.src.language == doc.matters.pod.manifest_list_of_languages[0]
) {
import sisudoc.outputs.io_out.po4a_cfg;
mixin spinePo4aConfig;
write(po4aConfig(doc.matters));
}
enum outTask { source_or_pod, sqlite, sqlite_multi, latex, typst, markdown, odt, epub, html_scroll, html_seg, html_stuff, text, skel }
void Scheduled(D)(int sched, D doc) {
auto msg = Msg!()(doc.matters);
if (sched == outTask.source_or_pod) {
msg.v("spine (doc reform) source processing... ");
if (doc.matters.opt.action.pod) { msg.v("spine (doc reform) source pod processing... "); }
import sisudoc.outputs.io_out.source_pod;
spinePod!()(doc.matters);
if (doc.matters.opt.action.source) { msg.vv("spine (doc reform) source done"); }
if (doc.matters.opt.action.pod) { msg.vv("spine (doc reform) source pod done"); }
}
if (sched == outTask.epub) {
msg.v("epub3 processing... ");
import sisudoc.outputs.io_out.epub3;
doc.outputEPub3!();
msg.vv("epub3 done");
}
if (sched == outTask.html_stuff) {
outputMetadata!()(doc.matters);
msg.vv("html metadata done");
}
if (sched == outTask.html_scroll) {
msg.v("html scroll processing... ");
import sisudoc.outputs.io_out.html;
outputHTML!().scroll(doc);
msg.vv("html scroll done");
}
if (sched == outTask.html_seg) {
msg.v("html seg processing... ");
import sisudoc.outputs.io_out.html;
outputHTML!().seg(doc);
msg.vv("html seg done");
}
if (sched == outTask.html_stuff) {
import sisudoc.outputs.io_out.html;
outputHTML!().css(doc.matters);
outputHTML!().images_cp(doc.matters);
msg.vv("html css & images done");
}
if (sched == outTask.latex) {
msg.v("latex processing... (available for downstream processing & pdf output");
import sisudoc.outputs.io_out.latex;
import std.file;
if ((isValidPath(doc.matters.output_path ~ "/latex/sty"))
&& (!(exists(doc.matters.output_path ~ "/latex/sty")))
) {
outputLaTeXstyInit!()(
doc.matters.output_path,
doc.matters.opt.action.generated_by,
doc.matters.generator_program.name_version_and_compiler,
doc.matters.generator_program.time_output_generated,
);
}
outputLaTeX!()(doc.abstraction, doc.matters);
msg.vv("latex done");
}
if (sched == outTask.typst) {
msg.v("typst processing... (the .typ, and the pdf when --pdf)");
import sisudoc.outputs.io_out.typst;
outputTypst!()(doc.abstraction, doc.matters);
if (doc.matters.opt.action.pdf) {
msg.v("typst compile to pdf... ");
outputTypstPdf!()(doc.matters);
}
msg.vv("typst done");
}
if (sched == outTask.markdown) {
msg.v("markdown processing... ");
import sisudoc.outputs.io_out.markdown;
outputMarkdown!()(doc.abstraction, doc.matters);
msg.vv("markdown done");
}
if (sched == outTask.text) {
msg.v("text processing... ");
import sisudoc.outputs.io_out.text;
outputText!()(doc.abstraction, doc.matters);
msg.vv("text done");
}
if (sched == outTask.odt) {
msg.v("odf:odt processing... ");
import sisudoc.outputs.io_out.odt;
outputODT!()(doc.abstraction, doc.matters);
msg.vv("odf:odt done");
}
if (sched == outTask.sqlite) {
msg.v("sqlite processing... ");
import sisudoc.outputs.io_out.sqlite_collection_db;
doc.SQLiteHubDiscreteBuildTablesAndPopulate!();
msg.vv("sqlite done");
}
if (sched == outTask.skel) {
msg.v("skel processing... ");
import sisudoc.outputs.io_out.skel;
outputSkel!()(doc.abstraction, doc.matters);
msg.vv("skel done");
}
}
if (doc.matters.opt.action.vox_gt_1) { writeln(doc.matters.src.filename_base); }
if (!(doc.matters.opt.action.parallelise_subprocesses)) {
foreach(schedule; doc.matters.opt.action.output_task_scheduler) {
Scheduled!()(schedule, doc);
}
} else {
import std.parallelism;
foreach(schedule; parallel(doc.matters.opt.action.output_task_scheduler)) {
Scheduled!()(schedule, doc);
}
}
if (doc.matters.opt.action.sqlite_update) {
msg.v("sqlite update processing...");
import sisudoc.outputs.io_out.sqlite_collection_db;
doc.SQLiteHubBuildTablesAndPopulate!();
msg.vv("sqlite update done");
} else if (doc.matters.opt.action.sqlite_delete) {
msg.v("sqlite delete processing...");
import sisudoc.outputs.io_out.sqlite_collection_db;
doc.SQLiteHubBuildTablesAndPopulate!();
msg.vv("sqlite delete done");
}
}
}
template outputHubInitialize() {
import std.file;
import sisudoc.outputs.io_out;
import sisudoc.outputs.io_out.metadata;
import sisudoc.outputs.io_out.paths_output;
string _bespoke_homepage = "./spine-bespoke-output/html/homepage.index.html";
@system void outputHubInitialize(O,I)(
O opt_action,
I program_info
) {
if ((opt_action.html || opt_action.html_seg || opt_action.html_scroll)
&& opt_action.output_dir_set.length > 0
&& !(opt_action.output_dir_set ~ "/index.html").exists
) {
writeln(_bespoke_homepage);
if ((_bespoke_homepage).exists) {
writeln("copy bespoke html homepage\n", _bespoke_homepage, " -> ", opt_action.output_dir_set, "/index.html");
_bespoke_homepage.copy(opt_action.output_dir_set ~ "/index.html");
} else {
writeln("place bespoke homepage in ", _bespoke_homepage);
}
}
if (
opt_action.latex_document_header_sty
|| (
opt_action.latex
&& opt_action.output_dir_set.length > 0
&& !(isValidPath(opt_action.output_dir_set ~ "/latex/sty")))
) { // .sty need to be produced only once (if unchanged per output-dir of which there usually will be only one)
import sisudoc.outputs.io_out.latex;
outputLaTeXstyInit!()(
opt_action.output_dir_set,
opt_action.generated_by,
program_info.name_version_and_compiler,
program_info.time_output_generated,
);
writeln(opt_action.latex);
}
}
}
template outputHubOp() {
import sisudoc.outputs.io_out;
import sisudoc.outputs.io_out.metadata;
import sisudoc.outputs.io_out.xmls;
import sisudoc.outputs.io_out.zip_pod;
import sisudoc.outputs.io_out.paths_output;
@system void outputHubOp(E,O,C)(E env, O opt_action, C config) {
if ((opt_action.sqlite_db_drop)) {
if ((opt_action.vox_gt_2)) {
writeln("sqlite drop db...");
}
import sisudoc.outputs.io_out.sqlite_collection_db;
SQLiteDbDrop!()(opt_action, config);
if ((opt_action.vox_gt_3)) {
writeln("sqlite drop db done");
}
}
if ((opt_action.sqlite_db_create)) {
if ((opt_action.vox_gt_2)) {
auto pth_sqlite_db = spinePathsSQLite!()(opt_action.cgi_sqlite_search_filename, opt_action.output_dir_set);
writeln("sqlite create table...");
}
import sisudoc.outputs.io_out.sqlite_collection_db;
SQLiteTablesCreate!()(env, opt_action, config);
if ((opt_action.vox_gt_3)) {
writeln("sqlite create table done");
}
}
}
}